Merge branch 'pr657'

.gitignore

@@ -6,3 +6,4 @@ ui_*
 qrc_*
 Makefile
 qtox
+*.qm

qtox.pro

@@ -37,17 +37,8 @@ FORMS    += \
     
 CONFIG   += c++11
 
-TRANSLATIONS = translations/de.ts \
+# Rules for creating/updating {ts|qm}-files
-               translations/fr.ts \
+include(translations/i18n.pri)
-               translations/it.ts \
-               translations/ru.ts \
-               translations/pirate.ts \
-               translations/pl.ts \
-               translations/fi.ts \
-               translations/mannol.ts \
-               translations/uk.ts \
-               translations/sv.ts \
-               translations/bg.ts
 
 RESOURCES += res.qrc
 

translations/i18n.pri

@@ -0,0 +1,39 @@
+# For autocompiling qm-files.
+
+TRANSLATIONS = translations/bg.ts \
+               translations/de.ts \
+               translations/fi.ts \
+               translations/fr.ts \
+               translations/it.ts \
+               translations/mannol.ts \
+               translations/pirate.ts \
+               translations/pl.ts \
+               translations/ru.ts \
+               translations/sv.ts \
+               translations/uk.ts
+
+#rules to generate ts
+isEmpty(QMAKE_LUPDATE) {
+    win32: QMAKE_LUPDATE = $$[QT_INSTALL_BINS]/lupdate.exe
+    else:  QMAKE_LUPDATE = $$[QT_INSTALL_BINS]/lupdate
+}
+
+#limitation: only on ts can be generated
+updatets.name = Creating or updating ts-files...
+updatets.input = _PRO_FILE_
+updatets.output = $$TRANSLATIONS
+updatets.commands = $$QMAKE_LUPDATE ${QMAKE_FILE_IN}
+updatets.CONFIG += no_link no_clean
+QMAKE_EXTRA_COMPILERS += updatets
+
+#rules for ts->qm
+isEmpty(QMAKE_LRELEASE) {
+    win32: QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease.exe
+    else:  QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
+}
+updateqm.name = Compiling qm-files...
+updateqm.input = TRANSLATIONS
+updateqm.output = ${QMAKE_FILE_PATH}/${QMAKE_FILE_BASE}.qm
+updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_PATH}/${QMAKE_FILE_BASE}.qm
+updateqm.CONFIG += no_link  no_clean target_predeps
+QMAKE_EXTRA_COMPILERS += updateqm